Hilfe zum FB MATERIAL_MAINTAIN_DARK

Die Frage ist als "gelöst" markiert. Den entsprechend Beitrag findest du hier.

SAP R/3 Materialwirtschaft: Einkauf, Bestandsführung, Rechnungsprüfung, Inventur, Bewertung, Leistungsabwicklung, Materialstamm...
3 Beiträge • Seite 1 von 1
3 Beiträge Seite 1 von 1

Hilfe zum FB MATERIAL_MAINTAIN_DARK

Beitrag von horst1959 (ForumUser / 20 / 0 / 0 ) »
Hallo,
ich weiß dass ist alles schon 100mal gefragt worden und es gibt auch 100 Antworten.
Die helfen mir alle nicht weiter. Meist nur irgendwo abgeschrieben ohne jeden Test ob der Inhalt auch als Code funktioniert.
Ich suche ein Beispiel für material_maintain_dark in welchem Felder Initial gemacht werden und wo das auch funktioniert.
Buchen klappt. Z_Felder klappen auch nach dem Customizing. Nur leer machen mag der Baustein nicht. Das Beispiel aus dem Netz mit MARC-EISBE habe ich schon getestet -> es geht nicht.

ERP Stand 7.40

Für ein funktionierendes Beispiel wäre ich sehr dankbar.

Gruß
HK

gesponsert
Stellenangebote auf ABAPforum.com schalten
kostenfrei für Ausbildungsberufe und Werksstudenten


Re: Hilfe zum FB MATERIAL_MAINTAIN_DARK

Beitrag von black_adept (Top Expert / 3943 / 105 / 886 ) »

Code: Alles auswählen.

REPORT.


DATA: lt_amara_ueb  TYPE STANDARD TABLE OF mara_ueb  WITH NON-UNIQUE DEFAULT KEY,
      lt_amvke_ueb  TYPE STANDARD TABLE OF mvke_ueb  WITH NON-UNIQUE DEFAULT KEY,
      lt_amfieldres TYPE STANDARD TABLE OF mfieldres WITH NON-UNIQUE DEFAULT KEY,
      lt_amerrdat   TYPE STANDARD TABLE OF merrdat   WITH NON-UNIQUE DEFAULT KEY.


PARAMETERS: p_matnr TYPE matnr OBLIGATORY,
            p_vkorg TYPE vkorg OBLIGATORY,
            p_vtweg TYPE vtweg OBLIGATORY.


*--------------------------------------------------------------------*
*Clear MVKE-PRAT1
*--------------------------------------------------------------------*


lt_amara_ueb = VALUE #( ( mandt = sy-mandt
                          matnr = p_matnr
                          pstat = 'V'
                          tcode = 'MM02'
                          tranc = 1
                          d_ind = 1 ) ).

lt_amvke_ueb = VALUE #( ( mandt = sy-mandt
                          matnr = p_matnr
                          vkorg = p_vkorg
                          vtweg = p_vtweg
                          tranc = 1
                          d_ind = 1 ) ).

*--------------------------------------------------------------------*
*Field to reset
*--------------------------------------------------------------------*
lt_amfieldres = VALUE #( ( fname = 'MVKE-PRAT1'
                           tranc = 1
                           d_ind = 1 ) ).

CALL FUNCTION 'MATERIAL_MAINTAIN_DARK'
  EXPORTING
    p_kz_no_warn           = 'X'
    kz_prf                 = 'W'
  TABLES
    amara_ueb              = lt_amara_ueb
    amvke_ueb              = lt_amvke_ueb
    amfieldres             = lt_amfieldres
    amerrdat               = lt_amerrdat
  EXCEPTIONS
    kstatus_empty          = 1
    tkstatus_empty         = 2
    t130m_error            = 3
    internal_error         = 4
    too_many_errors        = 5
    update_error           = 6
    error_propagate_header = 7
    OTHERS                 = 8.
IF sy-subrc <> 0.
  DATA(ls_syst) = syst.
  MESSAGE ID ls_syst-msgid TYPE 'I' NUMBER ls_syst-msgno
      WITH ls_syst-msgv1 ls_syst-msgv2 ls_syst-msgv3 ls_syst-msgv4 DISPLAY LIKE 'E'.
ELSE.
 break-point.  " See errormessage in lt_amerrdat or use utilitfunction to display errortable
ENDIF.
live long and prosper
Stefan Schmöcker

email: stefan@schmoecker.de

Re: Hilfe zum FB MATERIAL_MAINTAIN_DARK

Beitrag von horst1959 (ForumUser / 20 / 0 / 0 ) »
Der geht! Ich danke Dir.

Gruß
HK

Seite 1 von 1

Vergleichbare Themen

4
Antw.
4561
Views
Material Maintain Dark
von queen » 09.06.2008 16:10 • Verfasst in ABAP® für Anfänger
5
Antw.
2031
Views
SE 11 Maintain Generator
von teerock » 28.06.2004 13:10 • Verfasst in ABAP® Core
4
Antw.
1055
Views
cl_md_bp_maintain=>maintain / Update BP
von littleJohn » 02.05.2023 10:31 • Verfasst in SAP HANA für Anfänger
1
Antw.
1533
Views
fetch material group,material account 3010 and Plant(WERKS)
von dragospirnut1 » 05.07.2017 12:27 • Verfasst in ABAP Objects®

Über diesen Beitrag



Die Frage ist als "gelöst" markiert. Den entsprechend Beitrag findest du hier.

Unterstütze die Community und teile den Beitrag für mehr Leser und Austausch

Aktuelle Forenbeiträge

Zwischensumme Adobe Forms
vor 2 Tagen von Lucyalison 1 / 64
Interne Tabelle
vor 5 Tagen von black_adept 2 / 133
MaLo-Checker in ABAP
vor einer Woche von A6272 6 / 254

Newsletter Anmeldung

Keine Beiträge verpassen! Wöchentlich versenden wir lesenwerte Beiträge aus unserer Community.
Die letzte Ausgabe findest du hier.
Details zum Versandverfahren und zu Ihren Widerrufsmöglichkeiten findest du in unserer Datenschutzerklärung.

Aktuelle Forenbeiträge

Zwischensumme Adobe Forms
vor 2 Tagen von Lucyalison 1 / 64
Interne Tabelle
vor 5 Tagen von black_adept 2 / 133
MaLo-Checker in ABAP
vor einer Woche von A6272 6 / 254

Unbeantwortete Forenbeiträge

Zwischensumme Adobe Forms
vor 2 Tagen von Lucyalison 1 / 64
Group Items auf einer Filterbar
vor einer Woche von Bright4.5 1 / 107
tRFC Transaktionen SM58
vor 4 Wochen von A6272 1 / 140