Gesplitteter Docking-Container

Code: Alles auswählen.

REPORT  ztest.

TABLES: mara, kna1.

DATA: gr_docking          TYPE REF TO cl_gui_docking_container,
      gr_split            TYPE REF TO cl_gui_easy_splitter_container,
      gr_alv_mara         TYPE REF TO cl_gui_alv_grid,
      gr_alv_kna1         TYPE REF TO cl_gui_alv_grid,
      gr_cont_top         TYPE REF TO cl_gui_container,
      gr_cont_but         TYPE REF TO cl_gui_container.

DATA: gt_mara TYPE TABLE OF mara,
      gt_kna1 TYPE TABLE OF kna1.

PARAMETERS: p_max TYPE i DEFAULT 100.
SELECT-OPTIONS: s_matnr FOR mara-matnr.
SELECT-OPTIONS: s_kunnr FOR kna1-kunnr.
SELECTION-SCREEN PUSHBUTTON /15(20) p_button USER-COMMAND refresh.


INITIALIZATION.
p_button = '@42@ ALV Refresh'.
* DockingContainer erzeugen
  CREATE OBJECT gr_docking
    EXPORTING
      side      = cl_gui_docking_container=>dock_at_left
      extension = 400.

* DockingContainer splitten
  CREATE OBJECT gr_split
    EXPORTING
      parent      = gr_docking
      orientation = 0.

  gr_cont_top = gr_split->top_left_container.
  gr_cont_but = gr_split->bottom_right_container.
* 1. ALV
  CREATE OBJECT gr_alv_mara
    EXPORTING
      i_parent      = gr_cont_top
      i_appl_events = 'X'.

  CALL METHOD gr_alv_mara->set_table_for_first_display
    EXPORTING
      i_save           = space
      i_default        = 'X'
      i_structure_name = 'MARA'
    CHANGING
      it_outtab        = gt_mara
    EXCEPTIONS
      OTHERS           = 4.

* 2. ALV
  CREATE OBJECT gr_alv_kna1
    EXPORTING
      i_parent      = gr_cont_but
      i_appl_events = 'X'.

  CALL METHOD gr_alv_kna1->set_table_for_first_display
    EXPORTING
      i_save           = space
      i_default        = 'X'
      i_structure_name = 'KNA1'
    CHANGING
      it_outtab        = gt_kna1
    EXCEPTIONS
      OTHERS           = 4.

AT SELECTION-SCREEN.
  IF sy-ucomm = 'REFRESH'.
    SELECT *
      UP TO p_max ROWS
      INTO TABLE gt_mara
      FROM mara
      WHERE matnr IN s_matnr.

    SELECT *
      UP TO p_max ROWS
      INTO TABLE gt_kna1
      FROM kna1
      WHERE kunnr IN s_kunnr.

    gr_alv_mara->refresh_table_display( ).
    gr_alv_kna1->refresh_table_display( ).
  ENDIF.

START-OF-SELECTION.