OBJ als Attachment per Mail

Code: Alles auswählen.

* Send Mail
    DATA: docdata    LIKE sodocchgi1,
          objpack    LIKE sopcklsti1 OCCURS 10 WITH HEADER LINE,
          objhead    LIKE solisti1   OCCURS 10 WITH HEADER LINE,
          objtxt     LIKE solisti1   OCCURS 10 WITH HEADER LINE,
          objbin     LIKE solisti1   OCCURS 10 WITH HEADER LINE,
          objhex     LIKE solix      OCCURS 10 WITH HEADER LINE,
          reclist    LIKE somlreci1  OCCURS  1 WITH HEADER LINE.


    DATA: tab_lines  TYPE i,
          doc_size   TYPE i,
          objdes(100).

* For the BOR attachment
    CONSTANTS:
      c_object_describe LIKE swotobjid-describe VALUE '*<OBJECT>*'.
    DATA:
      l_object      TYPE swotobjid,
      l_objheader   LIKE soxobj.


* Create Message Body
*   Main Text
    objtxt = 'Test Document.'.
    APPEND objtxt.
    objtxt = 'You will find a BOR object attachment in message.'.
    APPEND objtxt.
    objtxt = 'Have a nice day.'.
    APPEND objtxt.

*   Title and Description
    DESCRIBE TABLE objtxt LINES tab_lines.
    READ     TABLE objtxt INDEX tab_lines.
    docdata-doc_size = ( tab_lines - 1 ) * 255 + strlen( objtxt ).
    docdata-obj_name  = 'BOR Object'.
    CONCATENATE 'BUS1001' '-' lv_matnr INTO objdes.
    CONCATENATE 'BOR Object' objdes 'as Attachment'
           INTO docdata-obj_descr SEPARATED BY space.
    CONDENSE docdata-obj_descr.

*   Write Packing List (Main)
    CLEAR objpack-transf_bin.
    objpack-head_start = 0.
    objpack-head_num   = 0.
    objpack-body_start = 1.
    objpack-body_num   = tab_lines.
    objpack-doc_type   = 'RAW'.
    APPEND objpack.

* Create OBJ attachment
    l_object-describe = c_object_describe.
    l_object-objtype  = 'BUS1001'.
    l_object-objkey   = lv_matnr.
    CALL FUNCTION 'OWN_LOGICAL_SYSTEM_GET'
      IMPORTING
        own_logical_system             = l_object-logsys
      EXCEPTIONS
        own_logical_system_not_defined = 1
        OTHERS                         = 2.
    IF sy-subrc <> 0.
      MESSAGE e398(00) WITH 'No Log Sys Found'.
    ENDIF.

    MOVE-CORRESPONDING l_object TO l_objheader.
    APPEND l_objheader TO objhead.

*   Write Packing List (Attachment)
    CLEAR objpack.
    objpack-head_start = 1.
    objpack-head_num   = 1.
    objpack-body_start = 0.
    objpack-body_num   = 0.
    objpack-doc_type   = 'OBJ'.
    objpack-obj_name   = 'BUS1001'.
    objpack-obj_descr  = objdes.
    APPEND objpack.

    LOOP AT lt_mail INTO ls_mail.
* Create receiver list
      reclist-receiver = ls_mail-mail.
      reclist-rec_type = 'U'.
      APPEND reclist.
    ENDLOOP.


* Send Message
    CALL FUNCTION 'SO_NEW_DOCUMENT_ATT_SEND_API1'
      EXPORTING
        document_data              = docdata
        put_in_outbox              = 'X'
        commit_work                = 'X'
      TABLES
        packing_list               = objpack
        object_header              = objhead
        contents_bin               = objbin
        contents_txt               = objtxt
        receivers                  = reclist
      EXCEPTIONS
        too_many_receivers         = 1
        document_not_sent          = 2
        document_type_not_exist    = 3
        operation_no_authorization = 4
        parameter_error            = 5
        x_error                    = 6
        enqueue_error              = 7
        OTHERS                     = 8.

    IF sy-subrc <> 0.
      MESSAGE ID 'SO' TYPE 'S' NUMBER '023'
              WITH docdata-obj_name.
    ENDIF.

  ENDIF.