CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Getting started ... Alles für einen gelungenen Start.
12 Beiträge • Seite 1 von 1
12 Beiträge Seite 1 von 1

CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von MartinZapf (ForumUser / 33 / 2 / 0 ) »
Hallo zusammen,

ich rufe den Baustein CVAPI_DOC_VIEW in einem RFC-Baustein auf. Bei den Tests im SAP macht er alles richtig, wenn der RFC-Baustein dann von extern aufgerufen wird, wird noch das ganze Coding durchlaufen, dann aber nach Aufruf von CVAPI_DOC_VIEW ein Fehler zurück gegeben -> Fehlercode 1 (Allg Fehler).

Meines Wissens nach kann man schon Nicht-RFC-fähige Bausteine in RFC-fähigen Bausteinen aufrufen!?!?

Was könnte es noch sein!

Falls ihr mehr Angaben braucht lasst es mich wissen.

Danke

Gruß
Martin

gesponsert
Stellenangebote auf ABAPforum.com schalten
kostenfrei für Ausbildungsberufe und Werksstudenten


Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von JHM (Top Expert / 1188 / 1 / 195 ) »
MartinZapf hat geschrieben:Meines Wissens nach kann man schon Nicht-RFC-fähige Bausteine in RFC-fähigen Bausteinen aufrufen!?!?

Was könnte es noch sein!
RFC-Aufrufe haben keine Verbindung zu einer GUI, wie sollen dann Befehle wie: cl_gui_frontend_services=>file_copy ausgeführt werden?
Gruß Hendrik

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von MartinZapf (ForumUser / 33 / 2 / 0 ) »
Hallo Hendrik,

danke für die Info.

Gibt es dann eine Alternative? Muss mich leider erst wieder ein bißchen im ABAP einfinden, war mal ne längere Zeit draussen aus dem Geschäft:-(

Danke

Gruß
Martin

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von MartinZapf (ForumUser / 33 / 2 / 0 ) »
Hallo miteinander,

muss den Beitrag mal wieder hochholen:-)

Das Unterfangen musste anderen Aufgaben weichen, wird nun aber wieder aktuell.

Hat jemand noch einen Tipp/Plan/Idee/Alternative zu obigen Problem?

Bin für jede Hilfe dankbar.

Danke:-)

Gruß
Martin

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von Thomas R. (Expert / 754 / 73 / 34 ) »
Hallo Martin,
nachdem die ursprüngliche technische Frage ja geklärt wurde sollten wir nun wissen, was konkret Deine Aufgabe ist, die Du mit dem FuBa lösen wolltest.

MfG
Thomas R.

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von MartinZapf (ForumUser / 33 / 2 / 0 ) »
Hallo Thomas,

von einem externen Programm wird die Rückmeldenummer eines Fertigungsauftrags an diesen Baustein übergeben. Zu dieser Rückmeldenummer ist ein Dokument hinterlegt welches geöffnet werden soll.

Bin leider noch nichts so firm deswegen der "Hilferuf" ;-)
RFC-Aufrufe haben keine Verbindung zu einer GUI, wie sollen dann Befehle wie: cl_gui_frontend_services=>file_copy ausgeführt werden?
Wie kann ich das dann bewerkstelligen?

Danke

Gruß

Martin

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von JHM (Top Expert / 1188 / 1 / 195 ) »
MartinZapf hat geschrieben:Wie kann ich das dann bewerkstelligen?
Du brauchst eine Funktion, die das Dokument ausliest und als Stream an den Aufrufer zurück gibt. Der Aufrufer muss sich um die Speicherung/Anzeige des Dokumentenstreams kümmern.

Kenn mich im DVS Umfeld nicht so gut aus, aber es gibt einen haufen FuBas, man muss nur den richtigen finden.
Gruß Hendrik

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von Thomas R. (Expert / 754 / 73 / 34 ) »
Hallo,
wir haben uns einen FuBa geschaffen, der die Links zu den Originalen zurückliefert. (Achtung, nur begrenzt gültig).
FuBa:

Code: Alles auswählen.

function z_dms_original_links.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     VALUE(IV_DOKAR) TYPE  DOKAR
*"     VALUE(IV_DOKNR) TYPE  DOKNR
*"     VALUE(IV_DOKVR) TYPE  DOKVR
*"     VALUE(IV_DOKTL) TYPE  DOKTL_D
*"  EXPORTING
*"     VALUE(ES_RETURN) TYPE  BAPIRET2
*"  TABLES
*"      ET_LINKS STRUCTURE  ZST_ORIGINAL_LINK
*"----------------------------------------------------------------------
* Do not use a table type for the returning parameter, the sap_RFC libary can't interpret it.
  data:
    lv_doc     type text30,
    lv_url     type dms_url,
    lt_ptxdata type dms_tbl_file,
    ls_phio_id type sdokobject.
  field-symbols:
    <ls_link> like line of et_links[],
    <ls_dms_rec_phio> type dms_rec_phio,
    <ls_ptxdata> like line of lt_ptxdata[].
*
  clear:
    et_links[],
    es_return.
*
  call function 'CONVERSION_EXIT_ALPHA_INPUT'
    exporting
      input  = iv_doknr
    importing
      output = iv_doknr.
*
  call function 'CV120_KPRO_MASTER_DATA_GET'
    exporting
      pf_dokar            = iv_dokar
      pf_doknr            = iv_doknr
      pf_dokvr            = iv_dokvr
      pf_doktl            = iv_doktl
*     PF_ACTIVE_ONLY      = ' '
*     PF_ACTIVE_ATTR_ONLY = ' '
*     PF_COMP_GET         = 'X'
*     PF_BAPI_CALL        =
    tables
      ptx_data            = lt_ptxdata[]
    exceptions
      not_found           = 1
      error               = 2
      others              = 99.
  if sy-subrc <> 0.
    if sy-msgid is initial.
      case sy-subrc.
        when 1.
          concatenate iv_dokar iv_doknr iv_dokvr iv_doktl into lv_doc separated by '|'.
*         Document '&1' not found
          message e002(hp) into es_return-message with lv_doc.
        when others.
*         &1: Unexpected failure &2! Inform the IT department!
          message e001(z_document_search) into es_return-message with 'CV120_KPRO_MASTER_DATA_GET' sy-subrc.
      endcase.
*   ELSE.
*     NOP - sy fields already filled
    endif.
    call function 'BALW_BAPIRETURN_GET2'
      exporting
        type   = sy-msgty
        cl     = sy-msgid
        number = sy-msgno
        par1   = sy-msgv1
        par2   = sy-msgv2
        par3   = sy-msgv3
        par4   = sy-msgv4
      importing
        return = es_return.
  else.
    loop at lt_ptxdata[] assigning <ls_ptxdata>.
      loop at <ls_ptxdata>-tbl_phios[] assigning <ls_dms_rec_phio>.
        ls_phio_id-class = <ls_dms_rec_phio>-ph_class.
        ls_phio_id-objid = <ls_dms_rec_phio>-ph_objid.
        call function 'CV120_KPRO_CHECKOUT_TO_URL'
          exporting
*           PF_BATCHMODE        =
            ps_phio_id          = ls_phio_id
*           PF_FILE             =
*           PF_STD_URL          = ' '
*           PF_DP_URL           = ' '
*           PF_COMP_GET         = ' '
          importing
            pfx_url             = lv_url
          exceptions
            error               = 1
            no_content          = 2
            others              = 99.
        if sy-subrc <> 0.
          if sy-msgid is initial.
*           &1: Unexpected failure &2! Inform the IT department!
            message e001(z_document_search) into es_return-message with 'CV120_KPRO_CHECKOUT_TO_URL' sy-subrc.
*         ELSE.
*           NOP - sy fields already filled
          endif.
          call function 'BALW_BAPIRETURN_GET2'
            exporting
              type   = sy-msgty
              cl     = sy-msgid
              number = sy-msgno
              par1   = sy-msgv1
              par2   = sy-msgv2
              par3   = sy-msgv3
              par4   = sy-msgv4
            importing
              return = es_return.
        else.
          insert initial line into table et_links[] assigning <ls_link>.
          <ls_link>-link = lv_url.
        endif.
      endloop.
    endloop.
  endif.
endfunction.
Die Struktur ZST_ORIGINAL_LINK besteht nur aus dem einen Element LINK mit dem Datenelement SO_URL.

Leider haben wir die üblichen Probleme mit eckigen Klammern usw.

MfG
Thomas R.

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von MartinZapf (ForumUser / 33 / 2 / 0 ) »
Hallo Thomas,

hab Deine Lösung eingebaut.

Die Frage aber nun. Was mach ich mit dem Link. Hast Du/Standard hier einen Baustein der die Datei anhand des Links öffnet?

Danke für Deine Hilfe.

Gruß
Martin

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von Thomas R. (Expert / 754 / 73 / 34 ) »
Hallo Martin,
Du bekommst ja einen kompletten http-link zurück, d.h. einfach an execute übergeben müsste gehen....
Bei uns ist eine Web-Applikation dahinter

MfG
Thomas R.

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von MartinZapf (ForumUser / 33 / 2 / 0 ) »
Hallo Thomas,

er bringt mir folgenden Link zurück:

http://192.168.142.43:8000/sarliis.dll? ... KoZIhvcNAQ

Die Datei die hier geöffnet werden sollte ist die AUF_2_54%202006-08-28%20083411.zip - Datei. Was allerdings gespeichert wird ist die sarliis.

Mein Aufruf schaut folgendermassen aus:

CALL METHOD cl_gui_frontend_services=>execute
EXPORTING
document = l_filename
operation = 'OPEN'
EXCEPTIONS
cntl_error = 1
error_no_gui = 2
bad_parameter = 3
file_not_found = 4
path_not_found = 5
file_extension_unknown = 6
error_execute_failed = 7
synchronous_failed = 8
not_supported_by_gui = 9
OTHERS = 10.

Kann/müssen noch andere Parameter übergeben werden?

Danke für Deine wirklich super schnelle Hilfe:-)

Gruß
Martin

Re: CVAPI_DOC_VIEW wirft Fehler in RFC-Baustein

Beitrag von Thomas R. (Expert / 754 / 73 / 34 ) »
Hallo Martin,
bei mir nicht.
Ich habe eben z.B. mit einem PDF getestet, das geht dann sofort im Browser auf.
Wenn Du mit ZIP arbeitest brauchst Du natürlich 7zip o.ä. auf Deinem Rechner mit der entsprechenden Endung verknüpft.

MfG
Thomas R.

Seite 1 von 1

Vergleichbare Themen

2
Antw.
2705
Views
Abrechnungsprotokoll wirft Meldung aus
von Alyaa » 04.03.2008 12:08 • Verfasst in Human Resources
3
Antw.
2277
Views
ABAP Lückentext wirft fragen auf...
von nico_ » 30.03.2012 10:46 • Verfasst in ABAP® für Anfänger
5
Antw.
2487
Views
Einfacher Subquery wirft Fehlermeldung
von stefanb » 05.12.2012 17:48 • Verfasst in ABAP® für Anfänger
2
Antw.
1087
Views
CDS VIEW: Mehrere Tabellen aus einer CDS View updaten
von Abapanfänger » 03.07.2019 10:46 • Verfasst in ABAP® für Anfänger
0
Antw.
1170
Views
Baustein ALM_ME_ORDER_USERSTATUS_CHANGE
von JensDA » 21.03.2011 13:32 • Verfasst in ABAP® Core

Über diesen Beitrag


Unterstütze die Community und teile den Beitrag für mehr Leser und Austausch

Aktuelle Forenbeiträge

Zwischensumme Adobe Forms
vor 2 Tagen von Lucyalison 1 / 64
Interne Tabelle
vor 5 Tagen von black_adept 2 / 133
MaLo-Checker in ABAP
vor einer Woche von A6272 6 / 254

Newsletter Anmeldung

Keine Beiträge verpassen! Wöchentlich versenden wir lesenwerte Beiträge aus unserer Community.
Die letzte Ausgabe findest du hier.
Details zum Versandverfahren und zu Ihren Widerrufsmöglichkeiten findest du in unserer Datenschutzerklärung.

Aktuelle Forenbeiträge

Zwischensumme Adobe Forms
vor 2 Tagen von Lucyalison 1 / 64
Interne Tabelle
vor 5 Tagen von black_adept 2 / 133
MaLo-Checker in ABAP
vor einer Woche von A6272 6 / 254

Unbeantwortete Forenbeiträge

Zwischensumme Adobe Forms
vor 2 Tagen von Lucyalison 1 / 64
Group Items auf einer Filterbar
vor einer Woche von Bright4.5 1 / 107
tRFC Transaktionen SM58
vor 4 Wochen von A6272 1 / 140