Exception Handler + Fehlerpopup

Die Frage ist als "gelöst" markiert. Den entsprechend Beitrag findest du hier.

Getting started ... Alles für einen gelungenen Start.
3 Beiträge • Seite 1 von 1
3 Beiträge Seite 1 von 1

Exception Handler + Fehlerpopup

Beitrag von sidneyweiher (ForumUser / 11 / 4 / 0 ) »
Hallo zusammen,

ich bin auf der Suche nach SAP-Standard-Bordmitteln, um eine Exception-Referenz der Hierarchie nach "aufzudröseln" und dann an ein (Fehler)-Pop-Up (normaler Dialog) zu übergeben. Gibt es dafür irgendwelche Standard-Funktionalitäten oder muss ich das komplett selbst bauen? Hat damit jmd Erfahrungen gemacht? Würde mich über eine Antwort freuen.
Vielen Dank für eure Hilfe und einen guten Start in die Woche!

gesponsert
Stellenangebote auf ABAPforum.com schalten
kostenfrei für Ausbildungsberufe und Werksstudenten


Re: Exception Handler + Fehlerpopup

Beitrag von DUTZMIC (ForumUser / 7 / 2 / 2 ) »
Zum Gruße!

Hatte vor kurzem erst das Thema, eine Standard-Lösung ist mir nicht bekannt, darum hab ich dann eine eigene Lösung entwickelt. Wenn du willst kannst du die ja einfach übernehmen ;)
Im Folgenden der Code, stammt aus einer Methode:

Parameter
Importing IO_CX TYPE REF TO CX_ROOT Ausnahmeklasse

Code: Alles auswählen.

  TYPES: BEGIN OF ty_message,
           index TYPE i,
           text  TYPE string,
         END OF ty_message.

  DATA: lt_messages TYPE TABLE OF ty_message,
        lv_index    TYPE i,
        lo_salv     TYPE REF TO cl_salv_table,
        lo_salv_col	TYPE REF TO cl_salv_columns_table,
        lo_cx       LIKE io_cx.

  FIELD-SYMBOLS: <fs_message> LIKE LINE OF lt_messages.

* Wenn die Ausnahmekette nur aus einem Objekt besteht, Nachricht in Statusleiste anzeigen
  IF io_cx->previous IS NOT BOUND.
    MESSAGE io_cx TYPE 'I' DISPLAY LIKE 'E'.
    RETURN.
  ENDIF.

* Nachrichten der gesamten Ausnahmekette ermitteln
  lo_cx = io_cx.
  WHILE lo_cx IS BOUND.
    INSERT INITIAL LINE INTO lt_messages ASSIGNING <fs_message> INDEX 1.
    <fs_message>-text = lo_cx->get_text( ).
    lo_cx = lo_cx->previous.
  ENDWHILE.

* Nachrichten der Reihenfolge des Auftretens nach nummerieren
  LOOP AT lt_messages ASSIGNING <fs_message>.
    ADD 1 TO lv_index.
    <fs_message>-index = lv_index.
  ENDLOOP.

* SALV mit Nachrichtentabelle erzeugen und anzeigen
  TRY.
      cl_salv_table=>factory(
        IMPORTING
          r_salv_table = lo_salv
        CHANGING
          t_table      = lt_messages ).

      lo_salv_col = lo_salv->get_columns( ).
      lo_salv_col->set_optimize( abap_true ).

      lo_salv->set_screen_popup(
        EXPORTING
          start_column = 16
          end_column   = 100
          start_line   = 1
          end_line     = 6 ).

      lo_salv->display( ).

    CATCH cx_salv_msg INTO DATA(lx).
      MESSAGE lx TYPE 'I' DISPLAY LIKE 'E'.
  ENDTRY.

Folgende Benutzer bedankten sich beim Autor DUTZMIC für den Beitrag (Insgesamt 2):
sidneyweiherewx


Re: Exception Handler + Fehlerpopup

Beitrag von sidneyweiher (ForumUser / 11 / 4 / 0 ) »
Vielen lieben Dank!!! :up: :up:

Seite 1 von 1

Vergleichbare Themen

8
Antw.
5949
Views
Handler- und ALV-Problem
von newbie007 » 10.12.2011 10:54 • Verfasst in ABAP Objects®
1
Antw.
1772
Views
Event Handler mit OLE
von snoodels » 10.12.2005 11:27 • Verfasst in ABAP Objects®
1
Antw.
4108
Views
ABAP RFC Remote Handler
von Shaguar » 31.08.2012 13:06 • Verfasst in Java & SAP®
0
Antw.
1255
Views
generischer Inbound Handler
von SvenSvenson » 08.05.2015 10:07 • Verfasst in ABAP Objects®
2
Antw.
2029
Views
Filter-Handler in ALV-Grid?
von abapnewbie » 30.07.2020 11:34 • Verfasst in ABAP Objects®

Über diesen Beitrag


Die Frage ist als "gelöst" markiert. Den entsprechend Beitrag findest du hier.

Unterstütze die Community und teile den Beitrag für mehr Leser und Austausch

Aktuelle Forenbeiträge

Zugriff auf Daten via Webdav
vor einer Stunde von msfox 2 / 36
Interne Tabelle
vor 18 Stunden von sap_enthusiast 3 / 163
Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71

Newsletter Anmeldung

Keine Beiträge verpassen! Wöchentlich versenden wir lesenwerte Beiträge aus unserer Community.
Die letzte Ausgabe findest du hier.
Details zum Versandverfahren und zu Ihren Widerrufsmöglichkeiten findest du in unserer Datenschutzerklärung.

Aktuelle Forenbeiträge

Zugriff auf Daten via Webdav
vor einer Stunde von msfox 2 / 36
Interne Tabelle
vor 18 Stunden von sap_enthusiast 3 / 163
Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71

Unbeantwortete Forenbeiträge

Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71
Group Items auf einer Filterbar
vor einer Woche von Bright4.5 1 / 111
tRFC Transaktionen SM58
vor 4 Wochen von A6272 1 / 141