CL_SALV_TABLE Überschriften

Die Frage ist als "gelöst" markiert. Den entsprechend Beitrag findest du hier.

Die Objektorientierung mit ABAP®: Vererbung, Dynamische Programmierung, GUI Controls (u.a. ALV im OO).
5 Beiträge • Seite 1 von 1
5 Beiträge Seite 1 von 1

CL_SALV_TABLE Überschriften

Beitrag von SAP_ENTWICKLER (Specialist / 445 / 219 / 6 ) »
Hallo,


ich nutze Methoden der CL_SALV_TABLE um mir einfache Grids anzeigen zu lassen.

Wie kann ich das erzeugte ALV mit verschiedenen Titeln anzeigen damit der User nicht immer erst durch den Inhalt der Spalten den 'Sinn' der Ausgabe erkennen kann?


Danke


Viele Grüße

Norbert

gesponsert
Stellenangebote auf ABAPforum.com schalten
kostenfrei für Ausbildungsberufe und Werksstudenten


Re: CL_SALV_TABLE Überschriften

Beitrag von zzcpak (Expert / 673 / 5 / 67 ) »
Du meinst die Spaltenüberschriften?

Dazu muss man sich ein wenig durch die diversen ALV-Klassen durchhangeln.

CL_SALV_COLUMNS_TABLE liefert eine Referenz auf die Spalten eines ALV.
CL_SALV_COMUMN dann auf einzelne Spalten dieser Liste.

Kurzes Beispiel:

Code: Alles auswählen.

TYPES:
  BEGIN OF itab_line,
    row1 TYPE i,
    row2 TYPE i,
  END OF itab_line.

DATA:
  itab        TYPE STANDARD TABLE OF itab_line,
  alv_list    TYPE REF TO cl_salv_table,
  column_list TYPE REF TO cl_salv_columns_table,
  column      TYPE REF TO cl_salv_column.


START-OF-SELECTION.

  TRY.
      cl_salv_table=>factory(
        IMPORTING
          r_salv_table = alv_list
        CHANGING
          t_table      = itab ).

      column_list = alv_list->get_columns( ).

      column = column_list->get_column( 'ROW1' ).
      column->set_short_text( 'Spalte 1' ).

      column = column_list->get_column( 'ROW2' ).
      column->set_medium_text( 'Spalte 2' ).

      alv_list->display( ).

    CATCH cx_salv_msg.
      "error handling

  ENDTRY.
Zum Setzen der Spaltenüberschriften existieren die drei Methoden
SET_SHORT_TEXT
SET_MEDIUM_TEXT
SET_LONG_TEXT

Folgende Benutzer bedankten sich beim Autor zzcpak für den Beitrag:
SAP_ENTWICKLER


Re: CL_SALV_TABLE Überschriften

Beitrag von SAP_ENTWICKLER (Specialist / 445 / 219 / 6 ) »
Nein, ich meine eine Überschrift der kompletten Tabelle.

Re: CL_SALV_TABLE Überschriften

Beitrag von zzcpak (Expert / 673 / 5 / 67 ) »
achso, sorry,
dann mit CL_SALV_DISPLAY_SETTINGS

Code: Alles auswählen.

DATA:
  itab             TYPE STANDARD TABLE OF t000,
  alv_list         TYPE REF TO cl_salv_table,
  display_settings TYPE REF TO cl_salv_display_settings.


START-OF-SELECTION.

  TRY.
      cl_salv_table=>factory(
        IMPORTING
          r_salv_table = alv_list
        CHANGING
          t_table      = itab ).

      display_settings = alv_list->get_display_settings( ).
      display_settings->set_list_header( 'Mein eigener Titel' ).

      alv_list->display( ).

    CATCH cx_salv_msg.
      "error handling

  ENDTRY.

Folgende Benutzer bedankten sich beim Autor zzcpak für den Beitrag:
SAP_ENTWICKLER


Re: CL_SALV_TABLE Überschriften

Beitrag von black_adept (Top Expert / 3942 / 105 / 885 ) »
Demoreport SALV_TEST_TABLE zeigt eigentlich alles was der SALV kann.

Oder wenn du es direkt ansprechen willst:
salv->GET_DISPLAY_SETTINGS( )->SET_LIST_HEADER( ... ).

Folgende Benutzer bedankten sich beim Autor black_adept für den Beitrag:
SAP_ENTWICKLER

live long and prosper
Stefan Schmöcker

email: stefan@schmoecker.de

Seite 1 von 1

Vergleichbare Themen

2
Antw.
5541
Views
Überschriften im Table Control ändern
von bjepegw » 07.10.2004 11:43 • Verfasst in Dialogprogrammierung
2
Antw.
3792
Views
Salv Table - Layouts speichern
von JohnLocklay » 14.06.2019 11:33 • Verfasst in ABAP Objects®
3
Antw.
1903
Views
GUI Status verhindert on click Event des SALV Table
von Pinguincommander » 05.02.2019 09:51 • Verfasst in ABAP® Core
3
Antw.
2633
Views
saplogon.ini Reihenfolge und Überschriften?
von cubarr » 21.09.2006 16:44 • Verfasst in SAP - Allgemeines
1
Antw.
923
Views
Überschriften in Recherche-Berichten
von Klaus1965 » 22.08.2005 16:18 • Verfasst in Financials

Über diesen Beitrag


Die Frage ist als "gelöst" markiert. Den entsprechend Beitrag findest du hier.

Unterstütze die Community und teile den Beitrag für mehr Leser und Austausch

Newsletter Anmeldung

Keine Beiträge verpassen! Wöchentlich versenden wir lesenwerte Beiträge aus unserer Community.
Die letzte Ausgabe findest du hier.
Details zum Versandverfahren und zu Ihren Widerrufsmöglichkeiten findest du in unserer Datenschutzerklärung.