Write-Ausgabe vor Alv-Grid Ausgabe

Getting started ... Alles für einen gelungenen Start.
8 Beiträge • Seite 1 von 1
8 Beiträge Seite 1 von 1

Write-Ausgabe vor Alv-Grid Ausgabe

Beitrag von L0w-RiDer (Expert / 535 / 83 / 2 ) »
Hallo,

ich habe ein Programm geschrieben und möchte bei diesem zunächst per Write-Befehl eine Liste ausgeben und im Anschluß eine andere Liste per ALV-Grid.

Wenn ich das bisher so richtig verstanden habe, werden die Write-Befehle nach Ende der Programmausführung ausgegeben. Also im Prinzip, wenn das Programm durchgelaufen ist. Wie schaffe ich es, zunächst die Write-Ausgabe anzeigen zu lassen und im Anschluß eine andere Tabelle per ALV.

Vielen Dank

gesponsert
Stellenangebote auf ABAPforum.com schalten
kostenfrei für Ausbildungsberufe und Werksstudenten


Re: Write-Ausgabe vor Alv-Grid Ausgabe

Beitrag von zzcpak (Expert / 673 / 5 / 67 ) »
Es gibt ja auch die Möglichkeit, im Kopfbereich des ALV Text auszugeben. Das wäre ggfs. eine sinnvolle Alternative. ALV und Listausgabe mit WRITE zu mischen ist irgendwie nicht so dolle. Alternativ hierrarchische Listen.

Re: Write-Ausgabe vor Alv-Grid Ausgabe

Beitrag von black_adept (Top Expert / 3943 / 105 / 886 ) »
WANN soll denn die ALV-Liste erscheinen?
Nach einer gewissen Zeit? Wenn der User einen bestimmten Button drückt?...

Alternativ könntest du sie ja auch gleichzeitig mit der Liste in einem Dock-Container anzeigen.
live long and prosper
Stefan Schmöcker

email: stefan@schmoecker.de

Re: Write-Ausgabe vor Alv-Grid Ausgabe

Beitrag von masterhash (ForumUser / 22 / 6 / 0 ) »
Andersrum wäre wohl einfacher, erst ALV und dann der WRITE

Code: Alles auswählen.

    g_obj->alv_show( ).

* Anzeige des User-Screens
    SET PF-STATUS 'RESULT'.
    WRITE / space.
So habe ich es "früher" gemacht, als ich noch keine Docking Container verwendet habe. Wenn der Status 'RESULT' eingerichtet ist, konnte man mit dem Zurück-Button vom ALV zum Screen mit dem Write gehen. Dort hatte ich dann immer diverse Buttons hinterlegt.
Das Vertauschen der von Methode und Write-Befehl bringt leider nicht die Lösung zu deinem Problem.

VG

kurzer Nachtrag:

Code: Alles auswählen.

    SET PF-STATUS `RESULT`.
    WRITE / space.

AT USER-COMMAND.
  CASE sy-ucomm.
    WHEN `LOG`.      PERFORM show_log.
    WHEN `ERGEBNIS`. PERFORM show_ergebnis.
    WHEN `EXIT`.     PERFORM exit.
  ENDCASE.
wenn du die Funktionscodes entsprechend einrichtest, kannst du dir erst den WRITE abholen und dann (zb: per Button ;) ) den ALV anzeigen lassen.

Re: Write-Ausgabe vor Alv-Grid Ausgabe

Beitrag von L0w-RiDer (Expert / 535 / 83 / 2 ) »
So ich habe mich nun entschieden, es mit einer Kopfzeile zu lösen.

Ich bin gerade dabei, bloß wird sie bisher garnicht angezeigt:

Sieht da jemand den Fehler??

Code: Alles auswählen.


DATA:  datex               TYPE c LENGTH 10,
      time(8)             TYPE c,
      gs_butxt2           TYPE c LENGTH 100,
      gr_alv              TYPE REF TO cl_salv_table,
      gr_columns          TYPE REF TO cl_salv_columns_table,
      gr_column           TYPE REF TO cl_salv_column_table,
      gr_header           TYPE REF TO cl_salv_form_layout_grid,
      gr_h_flow           TYPE REF TO cl_salv_form_layout_flow.

Try.
  cl_salv_table=>factory(
      IMPORTING
        r_salv_table   =  gr_alv
      CHANGING
        t_table        = it_kopk
    ).
  CATCH cx_salv_msg.
ENDTRY.

  gr_columns = gr_alv->get_columns( ).
  gr_columns->set_optimize( abap_true ).

" Erzeugung eines Objektes für die
" Überschrift.
  CREATE OBJECT gr_header.

" Funktionsaufruf um das Datum in einer
" anderen Ausgabenart anzeigen zu lassen.
  CALL FUNCTION 'FORMAT_DATE_4_OUTPUT'
    EXPORTING
    datin         = sy-datum
    format        = 'DD.MM.YYYY'
    IMPORTING
    datex         = datex.

" Verbindung von der Uhrzeit in die Variable Time
" um die Uhrzeit in einer anderen Ausgabenart anzeigen
" zu lassen.
  CONCATENATE sy-uzeit(2) ':' sy-uzeit+2(2) ':' sy-uzeit+4(2)
  INTO time.

" setzen einer Kopfzeile der internen Tabelle
" in der ALV-Grid Darstellung. Es soll ein Text,
" Datum und Uhrzeit erscheinen.
  gr_h_flow = gr_header->create_flow( row = 1  column = 1 ).
  CONCATENATE: 'Kreditorennummern:'
  datex '/' time '/' sy-uname
  INTO gs_butxt2 SEPARATED BY space.
  gr_h_flow->create_text( text = gs_butxt2 ).
  CLEAR gs_butxt2.

" Setzen einer Leerzeile.
  gr_h_flow = gr_header->create_flow( row = 2  column = 1 ).
  gs_butxt2 = ''.
  gr_h_flow->create_text( text = gs_butxt2 ).
  CLEAR gs_butxt2.

" Setzen einer Kopfzeile und Anzeige der aus der Liste
" gelöschten.
  gr_h_flow = gr_header->create_flow( row = 3  column = 1 ).
  gs_butxt2 = 'Folgende Verträge:'.
  gr_h_flow->create_text( text = gs_butxt2 ).

  " Setzen einer Leerzeile.
  gr_h_flow = gr_header->create_flow( row = 4  column = 1 ).
  gs_butxt2 = ''.
  gr_h_flow->create_text( text = gs_butxt2 ).
  CLEAR gs_butxt2.

" Einschalten der Funktionssymbole vom ALV-Grid.
  gr_alv->get_functions( )->set_all( abap_true ).

" Ausgabe der Daten per ALV-Grid.
  gr_alv->display( ).


sind natürlich nur die relevanten Codefragmente :).

Dankeschön!

Re: Write-Ausgabe vor Alv-Grid Ausgabe

Beitrag von qyurryus (Specialist / 107 / 81 / 45 ) »
Falls ich nichts übersehen habe setzt du gr_header nie als header im SALV. Fehlt also:

Code: Alles auswählen.

    gr_alv->set_top_of_list( gr_header ).

Folgende Benutzer bedankten sich beim Autor qyurryus für den Beitrag:
L0w-RiDer


Re: Write-Ausgabe vor Alv-Grid Ausgabe

Beitrag von L0w-RiDer (Expert / 535 / 83 / 2 ) »
Super es hat nun funktioniert.

Ich hätte nun noch eine Frage und zwar, weiß jemand wie man eine Spalte mit dem blau für Key-Feld kennzeichnen kann??

Re: Write-Ausgabe vor Alv-Grid Ausgabe

Beitrag von schick (ForumUser / 52 / 5 / 15 ) »
Hi,

ungefähr so müsste es möglich sein die Spalten einzufärben:

Code: Alles auswählen.

  METHOD set_colors.
    DATA: gr_coltab TYPE REF TO cl_salv_column_table.
    TRY.
        gr_coltab = CAST cl_salv_column_table( co_alv->get_columns( )->get_column( 'SPALTE1' ) ).
        gr_coltab->set_color( VALUE #( col = 1 int = 1 inv = 1 ) ).
      CATCH cx_salv_not_found ##NO_HANDLER.
    ENDTRY.
  ENDMETHOD.                    "set_colors

Seite 1 von 1

Vergleichbare Themen

10
Antw.
3407
Views
WRITE Ausgabe auf einem Dynpro
von Paul » 30.10.2018 14:39 • Verfasst in ABAP® für Anfänger
11
Antw.
2541
Views
Ordnen folgender WRITE-Ausgabe
von hmaxi96 » 17.03.2016 14:05 • Verfasst in ABAP® für Anfänger
3
Antw.
1811
Views
Write Ausgabe mit Feldern dynamisch gestalten
von Hagbard » 25.08.2005 09:52 • Verfasst in ABAP® für Anfänger
13
Antw.
6049
Views
ALV-Grid Ausgabe
von frany*89* » 02.09.2011 11:09 • Verfasst in ABAP® für Anfänger
12
Antw.
4394
Views
Problem ALV-GRID Ausgabe
von TobiB » 17.10.2007 17:31 • Verfasst in ABAP® für Anfänger

Aktuelle Forenbeiträge

Zugriff auf Daten via Webdav
vor 40 Minuten von msfox 2 / 34
Interne Tabelle
vor 17 Stunden von sap_enthusiast 3 / 163
Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71

Newsletter Anmeldung

Keine Beiträge verpassen! Wöchentlich versenden wir lesenwerte Beiträge aus unserer Community.
Die letzte Ausgabe findest du hier.
Details zum Versandverfahren und zu Ihren Widerrufsmöglichkeiten findest du in unserer Datenschutzerklärung.

Aktuelle Forenbeiträge

Zugriff auf Daten via Webdav
vor 40 Minuten von msfox 2 / 34
Interne Tabelle
vor 17 Stunden von sap_enthusiast 3 / 163
Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71

Unbeantwortete Forenbeiträge

Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71
Group Items auf einer Filterbar
vor einer Woche von Bright4.5 1 / 111
tRFC Transaktionen SM58
vor 4 Wochen von A6272 1 / 141