Selektion mit Eingabefenster statt PARAMETERS etc.

Code: Alles auswählen.

SUB_HEAD	SubSc	1	1	75	7	3
CONTROL	CuCtr	5	1	75	75	6 
SUB_FOOT	SubSc	12	1	75	75	3

Code: Alles auswählen.

 
PROCESS BEFORE OUTPUT.
* SubScreen für Überschrift einbinden
 CALL SUBSCREEN sub_head INCLUDING sy-repid '1002'.
* SubScreen für Datei einbinden
 CALL SUBSCREEN sub_foot INCLUDING sy-repid '1003'.

*Texteditcontroll erstellen
 MODULE INIT_1001.

PROCESS AFTER INPUT.
* SubScreen für Überschrift
 CALL SUBSCREEN sub_head.
* SubScreen für Datei 
 CALL SUBSCREEN sub_foot.
* Text aus Texteditcontrol hohlen
 MODULE GET_TEXT_1001.

Code: Alles auswählen.

REPORT irgendwas.

************************************************************************
*                     DATA-DEFINITION                                  *
************************************************************************
DATA:
*   texteditor
    g_editor    TYPE REF TO cl_gui_textedit,
*   Custom Controll
    g_container TYPE REF TO cl_gui_custom_container,
*   Text des Editos
    gt_tab(256) TYPE c OCCURS 0,
    gw_tab(256) TYPE c.

************************************************************************
*                     SELECTION SCREEN                                 *
************************************************************************
* Selection-Screen mit 1 Tabreiter, welcher das Dynpro 1001 als Subscreen einbindet
  SELECTION-SCREEN BEGIN OF TABBED BLOCK tab1 FOR 10 LINES.
  SELECTION-SCREEN TAB (50) tb1 USER-COMMAND '' DEFAULT SCREEN 1001.
  SELECTION-SCREEN END OF BLOCK tab1.

* Selection Screen für die Überschrift, wird von Dynpro 1001 als Subscreen eingebunden
  SELECTION-SCREEN BEGIN OF SCREEN 1002 AS SUBSCREEN.
  PARAMETERS: p_ueber TYPE char128.
  SELECTION-SCREEN END   OF SCREEN 1002.

* Selection Screen für die Datei, wird von Dynpro 1001 als Subscreen eingebunden
  SELECTION-SCREEN BEGIN OF SCREEN 1003 AS SUBSCREEN.
  PARAMETERS p_datei LIKE rlgrap-filename.
  SELECTION-SCREEN END   OF SCREEN 1003.
************************************************************************
*                      INITIALIZATION                                  *
************************************************************************
INITIALIZATION.
  tb1 = '@3J@Text pflegen'. "Tabreiter mit Überschrift und Icon versorgen

************************************************************************
*                     START-OF-SELECTION                               *
************************************************************************
START-OF-SELECTION.
* Eingaben vom SelectionScreen:
* Überschrift ausgeben
  WRITE: / p_ueber.
* Text ausgeben
  LOOP AT gt_tab INTO gw_tab.
    WRITE: / gw_tab.
  ENDLOOP.
* Link auf Datei ausgeben
  WRITE: / p_datei.

************************************************************************
*                          FORMS                                       *
************************************************************************
*---------------------------------------------------------------------*
*      Module  INIT_1001  OUTPUT
*---------------------------------------------------------------------*
*      Initialisieren des Controls, Aufbau des Textedit-Control
*---------------------------------------------------------------------*
MODULE init_1001 OUTPUT.
* Wenn Editor noch nicht gestartet dies hier tun:
  IF g_editor IS INITIAL.
    CREATE OBJECT g_container
       EXPORTING
           container_name = 'CONTROL'
       EXCEPTIONS
           cntl_error = 1
           cntl_system_error = 2
           create_error = 3
           lifetime_error = 4
           lifetime_dynpro_dynpro_link = 5.

    IF sy-subrc NE 0.
*      add your handling
    ENDIF.

    CREATE OBJECT g_editor
      EXPORTING
        parent                     = g_container
        wordwrap_mode              = cl_gui_textedit=>wordwrap_at_fixed_position
        wordwrap_to_linebreak_mode = cl_gui_textedit=>true.

  ENDIF.
ENDMODULE.                 " INIT_1001  OUTPUT
*---------------------------------------------------------------------*
*      Module  GET_TEXT_1001  INPUT
*---------------------------------------------------------------------*
*       Hohlt den Text aus dem Textcontrol
*---------------------------------------------------------------------*
MODULE get_text_1001 INPUT.
*-- Aktuellen Inhalt des TextEditControls lesen
  CALL METHOD g_editor->get_text_as_r3table
    IMPORTING
      table = gt_tab.
ENDMODULE.                 " GET_TEXT_1001  INPUT

************************************************************************
*                      END OF SCOURCE                                  *
************************************************************************