Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Ausgabe

Getting started ... Alles für einen gelungenen Start.
8 Beiträge • Seite 1 von 1
8 Beiträge Seite 1 von 1

Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Ausgabe

Beitrag von reim95 (ForumUser / 49 / 0 / 1 ) »
Hallo Liebe ABAP Forum User,

Ich bin blutiger ABAP Anfänger und plage mich seit tagen mit dem Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC herum.
Die Ausgabe funktioniert jetzt mal bei mir, aber ich würde gerne mit dem Baustein bei der Ausgabe eine Zeile bearbeiten oder hinzufügen und dies dann in eine Z Tabelle weg schreiben und sichern.


bei mir sieht das ganze jetzt mal so aus:

Code: Alles auswählen.

DATA: lv_repid  TYPE sy-repid,
      l_layout  TYPE lvc_s_layo,
      lt_fcat   TYPE lvc_t_fcat,
      ls_layout TYPE lvc_s_layo,
      lt_events TYPE lvc_t_fcat,
      z_title   TYPE lvc_title.


FORM tabelle USING zzan*****.

  CONCATENATE ' Pflege von der Anlage ' zzan***** INTO z_title RESPECTING BLANKS.

*l_layout-EDIT = 'X'.

  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
    EXPORTING
*     I_INTERFACE_CHECK  = ' '
*     I_BYPASSING_BUFFER =
*     I_BUFFER_ACTIVE    =
      i_callback_program = sy-repid
*     I_CALLBACK_PF_STATUS_SET          = ' '
*     I_CALLBACK_USER_COMMAND           = ' '
*     I_CALLBACK_TOP_OF_PAGE            = ' '
*     I_CALLBACK_HTML_TOP_OF_PAGE       = ' '
*     I_CALLBACK_HTML_END_OF_LIST       = ' '
*     I_STRUCTURE_NAME   =
*     I_BACKGROUND_ID    = ' '
      i_grid_title       = z_title
*     I_GRID_SETTINGS    =
      is_layout_lvc      = l_layout
      it_fieldcat_lvc    = lt_fcat
*     IT_EXCLUDING       =
*     IT_SPECIAL_GROUPS_LVC             =
*     IT_SORT_LVC        =
*     IT_FILTER_LVC      =
*     IT_HYPERLINK       =
*     IS_SEL_HIDE        =
*     I_DEFAULT          = 'X'
      i_save             = 'A'
*     IS_VARIANT         =
*     IT_EVENTS          =
*     IT_EVENT_EXIT      =
*     IS_PRINT_LVC       =
*     IS_REPREP_ID_LVC   =
*     I_SCREEN_START_COLUMN             = 0
*     I_SCREEN_START_LINE               = 0
*     I_SCREEN_END_COLUMN               = 0
*     I_SCREEN_END_LINE  = 0
*     I_HTML_HEIGHT_TOP  =
*     I_HTML_HEIGHT_END  =
*     IT_ALV_GRAPHICS    =
*     IT_EXCEPT_QINFO_LVC               =
*     IR_SALV_FULLSCREEN_ADAPTER        =
* IMPORTING
*     E_EXIT_CAUSED_BY_CALLER           =
*     ES_EXIT_CAUSED_BY_USER            =
    TABLES
      t_outtab           = zzan*****
* EXCEPTIONS
*     PROGRAM_ERROR      = 1
*     OTHERS             = 2
    .
  IF sy-subrc <> 0.
* Implement suitable error handling here
  ENDIF.

ENDFORM.

FORM alv_itab_fcat
  CHANGING ct_fcat TYPE lvc_t_fcat.

  DATA: ls_fcat TYPE lvc_s_fcat.
* Field =
**  ls_fcat-fieldname   = 'GOV***'.       "Feldname interne Tabelle
*  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
*  ls_fcat-key         = 'X'.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
*  ls_fcat-reptext  = ' Anlage'.

*  APPEND ls_fcat TO ct_fcat.
*  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'CODE'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = 'X'.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' Code '.
  ls_fcat-col_pos     = 1.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
** Field =
  ls_fcat-fieldname   = 'MATNR'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = 'X'.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = '  Material  '.
  ls_fcat-col_pos = 2.
  ls_fcat-no_zero =  'X'.
  ls_fcat-col_pos     = 2.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'MATTXT'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-no_zero =  'X'.
  ls_fcat-reptext  = ' Material-Text '.
  ls_fcat-outputlen = 30.
  ls_fcat-col_pos     = 3.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'MATDESC'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' Materialkurztext '.
  ls_fcat-outputlen = 20.
  ls_fcat-col_pos     = 4.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.

* Field =
  ls_fcat-fieldname   = 'TOL_1'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' 1.Toleranz '.
  ls_fcat-col_pos     = 5.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'TOL_GW1'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' Min.Menge '.
  ls_fcat-col_pos     = 6.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.

* Field =
  ls_fcat-fieldname   = 'TOL_2'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' 2.Toleranz '.
  ls_fcat-col_pos     = 7.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'TOL_GW2'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' Max.Menge '.
  ls_fcat-col_pos     = 8.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'TOL_3'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' 3.Toleranz '.
  ls_fcat-col_pos     = 9.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'MEINH'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' Mengeneinheit '.
  ls_fcat-col_pos     = 10.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'COMENGE'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' Anlage '.
  ls_fcat-col_pos     = 11.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.
* Field =
  ls_fcat-fieldname   = 'ARBPL'.       "Feldname interne Tabelle
  ls_fcat-ref_table   = 'ZZGOV***'.    "Tabellenname typisierte Tabelle
  ls_fcat-key         = ' '.           "Spalte ist Key-Spalte (blau und fix beim Scrollen)
  ls_fcat-reptext  = ' Arbeitsplatz '.
  ls_fcat-col_pos     = 12.
  APPEND ls_fcat TO ct_fcat.
  CLEAR ls_fcat.

Ich hoffe es kann mir irgendjemand weiter helfen.
Bitte auch vielleicht im Anfängerstil erklären.

llg Manuel

gesponsert
Stellenangebote auf ABAPforum.com schalten
kostenfrei für Ausbildungsberufe und Werksstudenten


Re: Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Aus

Beitrag von ralf.wenzel (Top Expert / 3776 / 176 / 262 ) »
Und wo genau ist jetzt dein Problem?

Ralf *Herr Doktor, mir tut was weh
Bild
Ralf Wenzel Heuristika SAP-Development
25 Jahre SAP-Entwickler • 20 Jahre Freiberufler
PublikationenUngarische NotationXing

Re: Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Aus

Beitrag von SaskuAc (Specialist / 321 / 37 / 43 ) »
ralf.wenzel hat geschrieben:Und wo genau ist jetzt dein Problem?

Ralf *Herr Doktor, mir tut was weh
Naja, da möchte jemand, dass wir ihm die Aufgaben machen ..

Zu dem "Problem":
Bitte lies dir die Doku zu dem Funktionsbaustein durch, dort wirst du, wenn es denn möglich ist, auf die Lösung stoßen. Ansonsten kann ich dir ( für editierbare ALV-Grids ) die Klasse CL_GUI_ALV_GRID empfehlen. Dazu gibt es hier im Forum schon einige Beiträge, einfach die Forumsuche verwenden.

Und noch ein kleiner Hinweis, wenn du in zukunft Quelltext postest, verwende doch bitte den "Code" button und füge dann den Code zwischen die Tags ein, dann ist er einfacher zu lesen ( zumindest im forum .. )

Re: Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Aus

Beitrag von reim95 (ForumUser / 49 / 0 / 1 ) »
ralf.wenzel hat geschrieben:Und wo genau ist jetzt dein Problem?

Ralf *Herr Doktor, mir tut was weh
schon wie oben beschrieben wäre das Problem, " ich würde gerne mit dem Baustein bei der Ausgabe eine Zeile bearbeiten oder hinzufügen und dies dann in eine Z Tabelle weg schreiben und sichern.".

Aber gut sowie SaskuAc schreibt, dass ich von euch eine Lösung erwarte, ist anscheinend hier kein Anfänger erwünscht der Unterstützung benötigt.
Denn in der SAP Doku finde ich leider nichts genaueres oder genauer gesagt weitere Hilfe für die Umsetzung.
Es sind alles so Brocken die ich mit meinem Wissen noch nicht zusammen fügen kann.
Des halb Hasse ich auch all diese Foren, denn diese Kommentare sind eigentlich nicht wirklich hilfreich.
Wenn ich es weiß und einem helfen will dann kann man ja auch mal einen Lösungsvorschlag schreiben anstand mühevoll eine Woche suchen, denn bevor man einen Beitrag öffnet sieht man sowieso das halbe Internet usw. ab.
aber ok trotzdem danke!

lg Manuel

Re: Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Aus

Beitrag von ralf.wenzel (Top Expert / 3776 / 176 / 262 ) »
Ich habe weder Zeit noch Lust, eine komplette Logik für das Bearbeiten und Speichern einer ALV-Tabelle in einer Z-Tabelle hier zu posten. Wenn jemand ein KONKRETES Problem hat, helfe ich gern.

So geht es hier sicher einigen. Wir müssen nebenher auch noch ein bisschen arbeiten.


Ralf
Bild
Ralf Wenzel Heuristika SAP-Development
25 Jahre SAP-Entwickler • 20 Jahre Freiberufler
PublikationenUngarische NotationXing

Re: Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Aus

Beitrag von Romaniac (Specialist / 198 / 57 / 26 ) »
Hallo Reim95 oder Manuel,

Es ist halt oft so dass viele hier was fragen ohne sich selbst die Mühe gemacht zu haben im Netz oderanderen Foren zu suchen, es ist halt in unserem Beruf so dass man sich manchmal entwas intensiver reinknien muss um was zu verstehen oder zu finden, der Lohn ist dass man es dann auch verstanden hat. Zum Thema editierbarer ALV gibt es sicher viele Treffer bei der Google Suche weil den so gut wieder jeder schon mal verwendet hat.

Hier mal ein paar Beispielprogramme von SAP zu diesem Thema:

BCALV_EDIT_01 Switch on and off the ready-for-input status of the entire grid
BCALV_EDIT_02 Define ready-for-input status at cell level
BCALV_EDIT_03 Verification of modified cells
BCALV_EDIT_04 Delete and append rows
BCALV_EDIT_05 Checkboxes
BCALV_EDIT_06 Dropdown Listbox at Column Level
BCALV_EDIT_07 Dropdown Listbox at Cell Level
BCALV_EDIT_08 Integrate Non-Standard F4 Help
BCALV_EDIT_09 Define ready-for-input status at cell level

Gruß Wolfgang
Geht nicht gibts nicht

Re: Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Aus

Beitrag von Legxis (Specialist / 160 / 90 / 28 ) »
Das findet man dazu online:

Code: Alles auswählen.

*---------------------------------------------------------------------*
* Report  ZZ_ALV_EDIT
*---------------------------------------------------------------------*

REPORT  zz_alv_edit LINE-SIZE 1000.

*** Variablen
DATA:
*** Pointer für CREATE DATA
gref           TYPE REF TO data,
*** Name der Datenbanktabelle
      gv_sname       LIKE dd02l-tabname VALUE 'MARA',
*** Feldkatalog
      gt_fcat        TYPE lvc_t_fcat.

*** Feld-Symbole
FIELD-SYMBOLS:
*** Feldkatalog
<fcat>      TYPE lvc_s_fcat,
*** Feld der Struktur
<feld>      TYPE ANY,
*** Arbeitsbereich der internen Tabelle
<wa>        TYPE ANY,
*** Die interne Tabelle mit Struktur aus GV_SNAME
<itab>      TYPE table.

*----------------------------------------------------------------------*
*       CLASS lcl_events DEFINITION
*----------------------------------------------------------------------*
CLASS lcl_events DEFINITION.

  PUBLIC SECTION.
    METHODS:
    handle_data_changed
    FOR EVENT data_changed  OF  cl_gui_alv_grid
    IMPORTING er_data_changed sender.

ENDCLASS.                    "lcl_events DEFINITION

*---------------------------------------------------------------------*
*       CLASS lcl_rohr_eventhandler IMPLEMENTATION
*---------------------------------------------------------------------*
CLASS lcl_events IMPLEMENTATION.

  METHOD handle_data_changed.
******************************************
*** HandleDataChanged                  ***
******************************************
    DATA: ls_good                TYPE lvc_s_modi.

*** alle Inhalte der geänderten Zellen in die interne Tabelle schreiben
    LOOP AT er_data_changed->mt_good_cells INTO ls_good.
*** Dazu auf die richtige Zeile in der ITAB positionieren:
      READ TABLE <itab> ASSIGNING <wa> INDEX ls_good-row_id.
      IF sy-subrc = 0.
*** Und das geänderte Feld dem Feldsymbol zuweisen
        ASSIGN COMPONENT ls_good-fieldname OF STRUCTURE <wa> TO <feld>.
        IF sy-subrc = 0.
*** Feldwert zuweisen
          <feld> = ls_good-value.
        ENDIF.
      ENDIF.
    ENDLOOP.
  ENDMETHOD.                    "handle_data_changed

ENDCLASS.                    "lcl_events IMPLEMENTATION

*** Variablen ALV
DATA:
      ref_alv        TYPE REF TO cl_gui_alv_grid,
      ref_container  TYPE REF TO cl_gui_custom_container,
      ref_alv_events TYPE REF TO lcl_events.


*** Programmstart
START-OF-SELECTION.

*** Aufruf des Dynpros
  CALL SCREEN 4000.

*&---------------------------------------------------------------------*
*&      Form  init
*&---------------------------------------------------------------------*
FORM init.

*** Container erzeugen
  CHECK ref_alv IS INITIAL.
  CREATE OBJECT ref_container
    EXPORTING
      container_name = 'ALV'.

  TRY.
*** Erzeugung der Datenstrukturen zur Laufzeit
      CREATE DATA gref TYPE STANDARD TABLE OF (gv_sname).
      ASSIGN gref->* TO <itab>.

*** Einlesen der Daten
      SELECT * FROM (gv_sname)
      INTO TABLE <itab>
      UP TO 10 ROWS.

*** Fehler abfangen
    CATCH cx_sy_create_data_error.
      WRITE 'Wrong Database!'.
  ENDTRY.

*** Feldkatalog einlesen
  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
      i_structure_name = gv_sname
    CHANGING
      ct_fieldcat      = gt_fcat
    EXCEPTIONS
      OTHERS           = 3.

*** Alle Felder editierbar machen
  LOOP AT gt_fcat ASSIGNING <fcat>.
    <fcat>-edit = 'X'.
  ENDLOOP.

*** ALV erzeugen
  PERFORM create_alv.

ENDFORM.                    "init

*&---------------------------------------------------------------------*
*&      Module  STATUS_4000  OUTPUT
*&---------------------------------------------------------------------*
MODULE status_4000 OUTPUT.

*** Status
  SET TITLEBAR '4000'.
  SET PF-STATUS 'STLI' OF PROGRAM 'SAPMSSY0'.

*** Clear
  CLEAR sy-ucomm.

*** Init ALV
  PERFORM init.

ENDMODULE.                 " STATUS_4000  OUTPUT

*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_4000  INPUT
*&---------------------------------------------------------------------*
MODULE user_command_4000 INPUT.

  CASE sy-ucomm.
    WHEN 'BACK' OR '%EX' OR 'RW'.
*** Liste
      LEAVE TO LIST-PROCESSING.
      SET PF-STATUS space.
*** Tabelleninhalt speichern
 *** Hier die <itab> in deine Z-Tabelle schreiben.
*** Exit
      SET SCREEN 0. LEAVE SCREEN.
  ENDCASE.

ENDMODULE.                 " USER_COMMAND_4000  INPUT

*&---------------------------------------------------------------------*
*&      Form  create_alv
*&---------------------------------------------------------------------*
FORM create_alv .

*** ALV anbinden
  CREATE OBJECT ref_alv
    EXPORTING
      i_parent      = ref_container
      i_appl_events = 'X'
    EXCEPTIONS
      OTHERS        = 5.

*** Edit-Event extra registrieren
  ref_alv->register_edit_event( i_event_id = cl_gui_alv_grid=>mc_evt_enter ).

*** Edit-Mode aktiv setzen
  ref_alv->set_ready_for_input( i_ready_for_input = 1 ).

*** ...und EventHandler zuweisen
  CREATE OBJECT ref_alv_events.
  SET HANDLER ref_alv_events->handle_data_changed FOR ref_alv.

*** First Display
  CALL METHOD ref_alv->set_table_for_first_display
    CHANGING
      it_fieldcatalog = gt_fcat
      it_outtab       = <itab>
    EXCEPTIONS
      OTHERS          = 4.

*** Fokus auf das Grid setzen
  cl_gui_alv_grid=>set_focus( ref_alv ).

*** Flush
  CALL METHOD cl_gui_cfw=>flush.

ENDFORM.                    " create_alv
Um diesen Code auszuführen musst du auf den Aufruf des Dynpros im Code klicken und dieses dann erstellen. Dann gehst du auf das Layout des Dynpro und fügst einen Custom Control ein, den du ALV nennst. Dann entfernst du die Kommentierung der Module im Code des Dynpro. Schlussendlich aktivierst du alles und kannst es dir anschauen und verstehen.
Du musst nurnoch deine Z-Tabelle erstellen und die Daten beim Beenden des ALVs reinschreiben, im Modul user_command_4000.

Wenn du es mit REUSE_ALV_GRID_DISPLAY machen willst, dann gibt es hier ein Beispiel (benötigt natürlich auch ein Dynpro): https://www.sapnuts.com/tutorials/Edit- ... -ABAP.html
( SAP ECC 6.0, NetWeaver 7.0, ohne unicode, ohne support/enhancement packages )

Re: Edit Funktionsbaustein REUSE_ALV_GRID_DISPLAY_LVC in Aus

Beitrag von SaskuAc (Specialist / 321 / 37 / 43 ) »
reim95 hat geschrieben: Aber gut sowie SaskuAc schreibt, dass ich von euch eine Lösung erwarte, ist anscheinend hier kein Anfänger erwünscht der Unterstützung benötigt.
Jeder Anfänger ist erwünscht .. Aber wie Romaniac schon schrieb:
Romaniac hat geschrieben:Es ist halt oft so dass viele hier was fragen ohne sich selbst die Mühe gemacht zu haben im Netz oderanderen Foren zu suchen, es ist halt in unserem Beruf so dass man sich manchmal entwas intensiver reinknien muss um was zu verstehen oder zu finden, der Lohn ist dass man es dann auch verstanden hat. Zum Thema editierbarer ALV gibt es sicher viele Treffer bei der Google Suche weil den so gut wieder jeder schon mal verwendet hat.
hat es eben für dich einen viel größeren Lerneffekt, wenn du es mit ( eventuell etwas mehr Aufwand ) selber heraus findest.

Wenn du Anfänger bist suche dir die SAP blogs ( tricktresor.de hat auch immer was feines im angebot ;) ) , die sind häufig sehr hilfreich, oder ein gutes Buch.

Außerdem wirst du doch nicht Anfänger sein & alleine die Sprache lernen. Du hast doch bestimmt einen Ausbilder / Professor / Tutor der dir helfen kann bei solchen Sachen. Keiner der dir eine Sprache beibringen soll wird dir den Kopf abreißen ( wir im übrigens auch nicht ) , wenn du mal etwas nicht weißt - im Gegenteil, es beeindruckt tatsächlich viele, wenn man zugibt, dass man Hilfe braucht und man zeigt, dass man lernen möchte. :-)

Ebenfalls wie Ralf schrieb:
ralf.wenzel hat geschrieben:Ich habe weder Zeit noch Lust, eine komplette Logik für das Bearbeiten und Speichern einer ALV-Tabelle in einer Z-Tabelle hier zu posten. Wenn jemand ein KONKRETES Problem hat, helfe ich gern.
Eine komplette Logik für eine editierbare ALV-Tabelle zu schreiben für eine Z-Tabelle ist auch relativ (zeit-)aufwendig.. außerdem kann man nicht einfach Code den man selber für einen Kunden geschrieben hat kopieren - könnte Datenschutz bestimmungen verletzen, was jemanden den Job kosten könnte .. ( gut etwas extrem ... aber in der theorie möglich .. ) und ich bin ehrlich, das will ich nicht riskieren .. --> man müsste sich hinsetzen und Code entweder komplett neu schreiben oder eben soweit anpassen, dass nicht mehr zu erkennen ist, was oder wer dahinter steckt.


Noch ein kleiner effekt, wenn du es selber probierst, ist, dass du für alle Probleme versuchst die Probleme selber zu suchen und dann eventuell tricks & kniffe entdeckst die noch nicht so bekannt sind - wenn du sowas nur kopierst, wirst du leider diesen prozess überspringen.


Einfach nicht krumm nehmen, wenn man in foren mal etwas harscher ist, als erwartet - wir wollen allerdings nur das beste ( auch wenn man das nicht immer glauben kann :')

Seite 1 von 1

Vergleichbare Themen

6
Antw.
4887
Views
Checkbox-Inhalt bei REUSE-ALV-GRID-DISPLAY-LVC
von Ucke » 19.11.2006 21:18 • Verfasst in ABAP® Core
0
Antw.
2066
Views
REUSE_ALV_GRID_DISPLAY_LVC Display zu Edit-Mode wechseln
von Flinners » 26.01.2007 16:50 • Verfasst in ABAP® Core
2
Antw.
2715
Views
REUSE _ ALV _ LIST _ DISPLAY - Zeile nicht markieren
von Gast » 12.09.2005 08:42 • Verfasst in ABAP® Core
4
Antw.
5887
Views
ALV Grid Display Variante speichern
von TCS » 18.06.2004 10:33 • Verfasst in ABAP® Core
1
Antw.
2300
Views
Page up and down im REUSE-ALV-Grid
von sapdepp » 24.08.2011 12:11 • Verfasst in ABAP® Core

Aktuelle Forenbeiträge

Zugriff auf Daten via Webdav
vor 15 Stunden von msfox 1 / 31
Interne Tabelle
vor 16 Stunden von sap_enthusiast 3 / 162
Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71

Newsletter Anmeldung

Keine Beiträge verpassen! Wöchentlich versenden wir lesenwerte Beiträge aus unserer Community.
Die letzte Ausgabe findest du hier.
Details zum Versandverfahren und zu Ihren Widerrufsmöglichkeiten findest du in unserer Datenschutzerklärung.

Aktuelle Forenbeiträge

Zugriff auf Daten via Webdav
vor 15 Stunden von msfox 1 / 31
Interne Tabelle
vor 16 Stunden von sap_enthusiast 3 / 162
Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71

Unbeantwortete Forenbeiträge

Zugriff auf Daten via Webdav
vor 15 Stunden von msfox 1 / 31
Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 71
Group Items auf einer Filterbar
vor einer Woche von Bright4.5 1 / 111